The Hammer » VDF Splat

//TH-Header

//*****************************************************************************************

// Copyright (c)  2013 Antwise Solutions

// All rights reserved.

//

// $FileName    : cDebugCJCommandBarSystem

// $ProjectName : Vdf Splat Debugger

// $Authors     : Wil van Antwerpen

// $Created     : 12.15.2013  02:28

// $Type        : GPLv2

//

// Contents:

//

//*****************************************************************************************

//TH-RevisionStart

//TH-RevisionEnd             

// these are all the packages used in a standard MDI menubar/toolbar system

Use cCJCommandBarSystem.pkg

Use cCJStandardMenuItemClasses.pkg

Use cCJAboutMenuItem.pkg

Use cDebugCJMenuItemClasses.pkg

Use cCJMDIWindowsMenuItem.pkg

//

Class cDebugCJCommandBarSystem is a cCJCommandBarSystem

  Procedure Construct_Object

    forward send Construct_Object

    Set pbTimerUpdate To True // must set this to dynamically update enabled state

  End_Procedure // Construct_Object

  // Code copied in from VDF17.1 to overcome the extremely ugly icons.

  // Auto excluded for higher VDF versions that have this fix already

#IF (FMAC_VERSION < 17)

//****** COPY CODE STARTS

    // Adds an image to imagelist. Pass if bmp or icon, the image name and the Id and image type (normal, disabled, etc.)

    // With Bitmaps this will first look for the resource then search for the file in the file path.

    // With Icons it checks for the file first (explained below)

    // return Image Id if success

    Function AddImageType Boolean bIsIcon String sImage Integer iId Integer eImageType Returns Integer

        Handle hBitmap

        Variant vImageManager

        Handle hoImageIcons

        Integer iVoid

        Boolean bOk 

        String sFileImage

        If (iId=0) Begin

            Get piLastImageId to iId

            Increment iId

            Set piLastImageId to iId

        End

        Get Create U_cCJImageManagerIcons to hoImageIcons

        Get ComIcons to vImageManager

        Set pvComObject of hoImageIcons to vImageManager

        // if an icon we will always try to load from a file first. Loading from a file works better than

        // the internal resource load because the internal load only finds the first image. If the ico has

        // multiple images (which CJ can use) all of the extra images are lost

        // if an Icon - load from file first then load from resource

        If bIsIcon Begin

            Get_File_Path sImage to sFileImage // find path in DFPATH, if appropriate

            If (sFileImage<>"") Begin

                Send ComLoadIcon of hoImageIcons sFileImage iId eImageType

                Move True to bOk

            End

            Else Begin

                Move (LoadImage(GetModuleHandle(0), sImage, IMAGE_ICON, 0, 0, 0)) to hBitmap

                If hBitmap Begin

                    // this works with alpha blends - even when passed false

                    Send ComAddIconHandle hBitmap iId eImageType False

                    Move (DestroyIcon(hBitmap)) to iVoid

                    Move True to bOk

                End

            End

        End

        // if a bitmap - load from resource first then from file

        Else Begin

            Move (LoadImage(GetModuleHandle(0), sImage, IMAGE_BITMAP, 0, 0, 0)) to hBitmap

            If (hBitmap=0) Begin // the bitmap was not in the EXE resource

                Get_File_Path sImage to sFileImage // find path in DFPATH, if appropriate

                If (sFileImage <>"") Begin // The image was found!

//                    Move (LoadImage(0, sFileImage, IMAGE_BITMAP, 0, 0, LR_LOADFROMFILE)) to hBitmap

                    Send ComLoadBitmap of hoImageIcons sFileImage iId eImageType

                    Move True to bOk

                End

            End

            If hBitmap Begin

                Send ComAddBitmap of hoImageIcons hBitmap iId eImageType False

                Move (DeleteObject(hBitmap)) to iVoid

                Move True to bOk

            End

        End

        Send destroy of hoImageIcons

        Function_Return (If(bOk, iId, 0))

    End_Procedure

    // Adds an image to imagelist. 

    // We assume that this is an icon unless the .bmp extension is passed. 

    // return True if success

    Function AddImage String sImage Integer iId Integer eImageType Returns Integer

        Boolean bIsIcon

        // Command Bars support many graphics formats including .bmp, .gif, .jpg etc.

        // These are all non-icon formats...

//        Move (Pos(".bmp", Lowercase(sImage)) = 0) to bIsIcon

        Move (Right(Lowercase(sImage), 4) = ".ico") to bIsIcon

        Get AddImageType bIsIcon sImage iId eImageType to iId

        Function_Return iId

    End_Procedure

//****** COPY CODE ENDS

#ENDIF

End_Class // cImageEditCJCommandBarSystem