The Hammer » VDF Splat

//TH-Header

//*****************************************************************************************

// Copyright (c)  2016 Antwise Solutions

// All rights reserved.

//

// $FileName    : VdfGuidance\VdfSplat\AppSrc\FindWindows.pkg

// $ProjectName : VdfSplat DataFlex Debugger

// $Authors     : Wil van Antwerpen

// $Created     : 10.26.2016  19:15

// $Type        : GPL v2

//

// Contents:

//

//*****************************************************************************************

//TH-RevisionStart

//TH-RevisionEnd

External_function GetDlgItem "GetDlgItem" User32.dll ;

   Handle hWnd ;

   Integer nIDDlgItem ;

   Returns Handle

// Find the handle to a window whose class name and window name match

// the specified strings. The Function searches child windows,

// beginning with the one following the specified child window.

External_function FindWindowEx "FindWindowExA" User32.dll ;

   Handle hWndParent ;

   Handle hWndChildAfter ;

   Pointer lpszClass ;

   Pointer lpszWindow ;

   Returns Handle

External_function GetClassName "GetClassNameA" user32.dll ;

   Handle hWnd ;

   Pointer lpClassName ;

   Integer nMaxCount ;

   Returns Integer

//Showln "Print some text"  // this creates the output window

// Finds the next windows child object given by parent window hWnd

// for class sClass

// The search is case insensitive

// If hWndChild = 0 the first child is returned.

// Returns: The windows handle of the child object if found

Function FindNextChildWindowByClass Handle hWnd Handle hWndChild String sClass Returns Handle

  String  sClassName

  Handle  lpsClassName

  Integer nChar

  Boolean bStop

  //Move (Left(Lowercase(sClass),10)) To sClass

  Move (Lowercase(sClass)) To sClass

  Move (False) To bStop

  While Not (bStop)

    //Showln "PARENT = " (IntToHex(hWnd))

    Move (FindWindowEx(hWnd,hWndChild,'','')) To hWndChild

    //Showln "FindWindowEx " (IntToHex(hWndChild))

    If (hWndChild=0) Begin

      // No Childs found, stop here

      Move (True) To bStop

    End

    Else Begin

      Move (Repeat(Character(0),80))      To sClassName

      GetAddress Of sClassName            To lpsClassName

      Move (GetClassName(hWndChild,lpsClassName,40)) To nChar

      If (nChar<>0) Begin

        Move (Left(Lowercase(Cstring(sClassName)),nChar)) To sClassName

        If (sClass=sClassName) Begin

          Move (True) To bStop

        End

      End

    End

  Loop

  Function_Return (hWndChild)

End_Function // FindNextChildWindowByClass

// Finds the first windows child object given by parent window hWnd

//

// If hWndChild = 0 the first child is returned.

// Returns: The windows handle of the child object if found

Function FindFirstChildWindowHandle Handle hWnd Returns Handle

  Handle hWndChild

  Move (FindWindowEx(hWnd,0,'','')) To hWndChild

  Function_Return hWndChild

End_Function // FindFirstChildWindowHandle

// Finds the next windows child object given by parent window hWnd

//

// Returns: The windows handle of the child object if found

Function FindNextChildWindowHandle Handle hWnd Handle hWndChild Returns Handle

  Handle hWndNextChild

  Move (FindWindowEx(hWnd,hWndChild,'','')) To hWndNextChild

  Function_Return hWndNextChild

End_Function // FindNextChildWindowHandle

Function WindowsClassnameForWindowsHandle Integer hWnd Returns String

  String  sClassName

  Handle  lpsClassName

  Integer nChar

  Move "" To sClassName

  If (hWnd<>0) Begin

    ZeroString 120 To sClassName

    GetAddress Of sClassName            To lpsClassName

    Move (GetClassName(hWnd,lpsClassName,119)) To nChar

    If (nChar<>0) Begin

      Move (Left(CString(sClassName),nChar)) To sClassName

    End

    Else Move "" To sClassname

  End

  Function_Return sClassName

End_Function // WindowsClassnameForWindowsHandle

Function WindowsClassname Integer hObject Returns String

  String  sClassName

  Handle  lpsClassName

  Handle  hWnd

  Integer nChar

  Move "" To sClassName

  If (hObject) Begin

    Move (Window_Handle(hObject)) To hWnd

    If (hWnd<>0) Begin

      Move (Repeat(Character(0),40))      To sClassName

      GetAddress Of sClassName            To lpsClassName

      Move (GetClassName(hWnd,lpsClassName,30)) To nChar

      If (nChar<>0) Begin

        Move (Left(Lowercase(CString(sClassName)),nChar)) To sClassName

      End

      Else Move "" To sClassname

    End

    Else Move "" To sClassname

  End

  Function_Return sClassName

End_Function // WindowsClassname