The Hammer » VDF Splat

//TH-Header

//*****************************************************************************************

// Copyright (c)  2013 Antwise Solutions

// All rights reserved.

//

// $FileName    : cDebuggerEngine

// $ProjectName : Splat ! Vdf Debugger

// $Authors     : Wil van Antwerpen

// $Created     : 12.14.2013  23:42

// $Type        : GPLv2

//

// Contents:

//

//*****************************************************************************************

//TH-RevisionStart

//TH-RevisionEnd

Use cIniFile.pkg

use VDFBase.pkg

Use vdfdebug.pkg

Use vWin32fh.pkg

Struct tBreakPoints

  Boolean  bEnabled

  String   sFileName

  UInteger iLine

  Boolean  bHasCondition

  String   sExpression

  String   sLine

End_Struct // tBreakPoints

//

// This mixin makes sure that all of the components sync up to the

// correct debugger version by asking the main component what vdf

// version it is.

//

Class cDebugComponentMixin is a Mixin

  Procedure DetermineRuntimeVersion

    Integer iRuntimeVersion

    Handle  hoDebugger

    Get phoDebugger To hoDebugger

    If (hoDebugger) Begin

      Get piRuntimeVersion of hoDebugger To iRuntimeVersion

      Set piRuntimeVersion to iRuntimeVersion

    End

  End_Procedure // DetermineRuntimeVersion

End_Class // cDebugComponentMixin

Class cCallStack is a cComCCallStack

  Import_Class_Protocol cDebugComponentMixin

  Procedure Construct_Object

    Forward Send Construct_Object

    Send Construct_Object_Callback

  End_Procedure // Construct_Object

  //

  // Mechanism to have the ability to set normal properties for the object

  // in the parent object view.

  //

  Procedure Construct_Object_Callback

    Handle hoParent

    Handle hoSelf

    Move Self To hoSelf

    Set phoCallStack     To hoSelf

    Get phoCallStackHost To hoParent // parent object

    If (hoParent) Begin

      Send CreateObjectCallback of hoParent hoSelf

    End

  End_Procedure // Construct_Object_Callback

// None of the below is being used

//

//  Procedure Mouse_Click Integer iWindows Integer iPos

//    send info_box ("call stack"+trim(iWindows)*"("*trim(iPos))

//    Forward Send Mouse_Click iWindows iPos

//  End_Procedure // Mouse_Click

//

//  Procedure Mouse_Click2 Integer iWindows Integer iPos

//    Send info_box ("call TWO stack"+trim(iWindows)*"("*trim(iPos))

//    Forward Send Mouse_Click2 iWindows iPos

//  End_Procedure // Mouse_Click

//

//  Procedure OnClick

//    Send info_box ("call THREE stack")

//    //Forward Send Mouse_Click2 iWindows iPos

//  End_Procedure // Mouse_Click

//

//  Procedure Mouse_Down integer iWindowNumber integer iPosition

//    Send info_box ("call THREE stack")

//      forward send Mouse_Down iWindowNumber iPosition

//      //send DoSomething of oMyObject

//  End_Procedure  // Mouse_Down

//

//   Procedure OnComMessageClicked UInteger llcommandNo

//     Send info_box ("call four stack")

//   End_Procedure

   //Procedure RepaintCallStack

   //  Handle hWindow hVoid

   //  Get Window_Handle To hWindow

   //  If hWindow Move (InvalidateRect(hWindow,0,True)) To hVoid

   //End_Procedure // RepaintCallStack

//

// entering is being called, not yet found a way on getting the items in the list

//

  Procedure Entering Returns Integer

    Integer Rval

    Integer iItem

    Integer iCount

    Forward Get Msg_Entering To Rval  // Do Normal Entering

    // if entering is ok and single item check shadow state of that item.

    If (Rval=0) Begin

      Get Item_Count To iCount

      Get Current_Item To iItem

//      Showln ("entering stack "+trim(iCount)*"current"*trim(iItem))

      //  Get Shadow_State Item 0 To Rval

    End

    Procedure_Return Rval

  End_Procedure

End_Class // cCallStack

Class cMessageTrace is a cComCMessageTrace

  Import_Class_Protocol cDebugComponentMixin

  Procedure Construct_Object

    Forward Send Construct_Object

    Send Construct_Object_Callback

  End_Procedure // Construct_Object

  //

  // Mechanism to have the ability to set normal properties for the object

  // in the parent object view.

  //

  Procedure Construct_Object_Callback

    Handle hoParent

    Handle hoSelf

    Move Self To hoSelf

    Set phoTrace     To hoSelf

    Get phoTraceHost To hoParent // parent object

    If (hoParent) Begin

      Send CreateObjectCallback of hoParent hoSelf

    End

  End_Procedure // Construct_Object_Callback

  Procedure OnComMessageClicked UInteger llcommandNo

    Handle  hoDebugger

    Handle  hoEditor

    Integer iLine

    String  sFileName

    //send info_box ("OnComMessageClicked "*trim(llcommandNo))

    Get phoDebugger To hoDebugger

    Get phoEditor   To hoEditor

    If (hoDebugger and hoEditor and llcommandNo>0) Begin

      // Returns the source line from the specified command number

      //

      Get ComGetSourceLineFromCommand Of hoDebugger llcommandNo (&iLine) To sFileName

      //Send ComOpenFile of oCodeMax sFileName

      ////Set ComLanguage    of oCodeMax To "VDF"

      //Set ComReadOnly Of oCodeMax To True // NO changes allowed

      //Set ComColorSyntax of oCodeMax To True

      //Send doSetCaptionLabel sFileName

      Send doOpenSourceFileAtLine Of hoEditor sFileName iLine

      //If (iLine>10) Begin

      //  Move (iLine-4) To iLine // scroll up a bit

      //End

      //Send ComSetTopIndex of oCodeMax 0 iLine

      //send info_box ("OnComMessageClicked "*trim(llline)*sFileName)

    End

  End_Procedure

End_Class // cMessageTrace

Class cTablesWindow is a cComCTablesWindow

  Import_Class_Protocol cDebugComponentMixin

  Procedure Construct_Object

    Forward Send Construct_Object

    Send Construct_Object_Callback

  End_Procedure // Construct_Object

  //

  // Mechanism to have the ability to set normal properties for the object

  // in the parent object view.

  //

  Procedure Construct_Object_Callback

    Handle hoParent

    Handle hoSelf

    Move Self To hoSelf

    Set phoTablesWindow To hoSelf

    Get phoTablesHost   To hoParent // parent object

    If (hoParent) Begin

      Send CreateObjectCallback of hoParent hoSelf

    End

  End_Procedure // Construct_Object_Callback

  Procedure OnComCmdAddWatch String llsExpression

    Handle hoWatches

    Get phoWatches To hoWatches

    If (hoWatches) Begin

      Send ComAddWatch Of hoWatches llsExpression

    End

  End_Procedure // OnComCmdAddWatch

End_Class // cTablesWindow

Class cVariablesWindow is a cComCVariablesWindow

  Import_Class_Protocol cDebugComponentMixin

  Procedure Construct_Object

    Forward Send Construct_Object

  End_Procedure // Construct_Object

  Procedure OnComCmdAddWatch String llsExpression

    Handle hoWatches

    Get phoWatches To hoWatches

    If (hoWatches) Begin

      Send ComAddWatch Of hoWatches llsExpression

    End

  End_Procedure // OnComCmdAddWatch

End_Class // cVariablesWindow

Class cWatches is a cComCWatches

  Import_Class_Protocol cDebugComponentMixin

  Procedure Construct_Object

    Forward Send Construct_Object

    Send Construct_Object_Callback

  End_Procedure // Construct_Object

  //

  // Mechanism to have the ability to set normal properties for the object

  // in the parent object view.

  //

  Procedure Construct_Object_Callback

    Handle hoParent

    Handle hoSelf

    Move Self To hoSelf

    Set phoWatches     To hoSelf

    Get phoWatchesHost To hoParent // parent object

    If (hoParent) Begin

      Send CreateObjectCallback of hoParent hoSelf

    End

  End_Procedure // Construct_Object_Callback

End_Class // cWatches

Class cDebuggerEngine is a cComCDebuggerEngine

  Procedure Construct_Object

    Forward Send Construct_Object

    Property String         psApplicationFileName ""

    Property String         psIdeSrcPath          ""

    Property String         psBPFileName          "Splat-Breakpoints.ini"

    Property Boolean        pbEngineActive        False

    Property Boolean pbProgramStarted      False

    Property Boolean pbProgramPaused       False

    Property String[]       pAllMessages

    Property String[]       pAllProperties

    Property tBreakPoints[] pBreakPoints

    Set Name To "oDebuggerEngine"

  End_Procedure // Construct_Object

  Procedure DetermineRuntimeVersion

    Integer iRuntime

    Get piDebugfileVersion to iRuntime

    Set piRuntimeVersion   to iRuntime

  End_Procedure // DetermineRuntimeVersion

    // Hackish way to determine the IdeSrc folder

  Procedure LocateIdeSrcFolder String sApplication

    String  sIdeSrcPath

    String  sFolderName

    String  sWSPath

    Boolean bExists

    Move "" To sIdeSrcPath

    If (sApplication<>"") Begin

      Get ParseFolderName sApplication To sFolderName

      Get vParentPath sFolderName To sWSPath

      Get vFolderFormat sWSPath To sWSPath

      Move (sWSPath+"IdeSrc\") To sIdeSrcPath

      Get vFolderExists sIdeSrcPath To bExists

      If (bExists=false) Begin

        Move "" To sIdeSrcPath

        Send Info_Box ("Not able to find IdeSrc Path from folder:\n"+sFoldername+"Some features such as load/save breakpoints will not work.") "Info"

      End

    End

    Set psIdeSrcPath To sIdeSrcPath

  End_Procedure

  Procedure Set ApplicationFileName String sApplication

    Set psApplicationFileName To sApplication

    Send LocateIdeSrcFolder sApplication

  End_Procedure

  //

  // Enumeraties the all messages array as it has all properties as well.

  // A property has 2 items in the array.

  // First a "get_<property name>"

  // followed up by a "set_<property name>"

  //

  // We simply create the array with "<property name>" based on what we find.

  //

  // All property names are in lower case (as is the message array)

  //

  Procedure getAllProperties

    Integer  iCount

    Integer  iMsg

    Integer  iProp

    String   sMessage

    String[] AllMessages

    String[] AllProperties

    Move 0 To iProp

    Move (ResizeArray(AllProperties,0)) To AllProperties

    Get pAllMessages to AllMessages

    Move (SizeOfArray(AllMessages)) To iCount

    Decrement iCount

    For iMsg from 1 to iCount

      if (iMsg<iCount) begin

        if (left(AllMessages[iMsg],4)="get_") Begin

          Move AllMessages[iMsg] To sMessage

          Move (replace("get_",sMessage,"set_")) To sMessage

          If (AllMessages[iMsg+1]=sMessage) Begin

            Move (replace("set_",sMessage,"")) To sMessage

            Move sMessage To AllProperties[iProp]

            Increment iProp

          End

          Else If (AllMessages[iMsg-1]=sMessage) Begin

            Move (replace("set_",sMessage,"")) To sMessage

            Move sMessage To AllProperties[iProp]

            Increment iProp

          End

        End

      End

    Loop

    // Add functions safe to evaluate. we'll do this different later on.. now testing

    // and the idea works.. hmmm :D

    Move "selectedrow" to AllProperties[iProp]

    Set pAllProperties to AllProperties

  End_Procedure

  Function IsVariableProperty String sVariable Returns Boolean

    Integer  iCount

    Integer  iProp

    Boolean  bIsProperty

    String[] AllProperties

    Move false to bisProperty

    Move (lowercase(sVariable)) To sVariable

    If (sVariable<>"") Begin

      Get pAllProperties to AllProperties

      Move (SizeOfArray(AllProperties)) To iCount

      Decrement iCount

      For iProp From 0 To iCount

        If (AllProperties[iProp]=sVariable) Begin

          Move True To bIsProperty

          Move iCount To iProp // stop

        End

      Loop

    End

    Function_Return bIsProperty

  End_function

  Function IsVariableProcedure String sVariable Returns Boolean

    Integer  iCount

    Integer  iMethod

    Boolean  bIsMethod

    String[] AllMessages

    Move false to bisMethod

    Move (lowercase(sVariable)) To sVariable

    If (sVariable<>"") Begin

      Move ("msg_"+sVariable) to sVariable

      Get pAllMessages to AllMessages

      Move (SizeOfArray(AllMessages)) To iCount

      Decrement iCount

      For iMethod From 0 To iCount

        If (AllMessages[iMethod]=sVariable) Begin

          Move True To bIsMethod

          Move iCount To iMethod // stop

        End

      Loop

    End

    Function_Return bIsMethod

  End_Function

  //

  // This will treat functions and properties both as function, so first

  // test if the variable isn't a property to exclude that.

  //

  Function IsVariableFunction String sVariable Returns Boolean

    Integer  iCount

    Integer  iMethod

    Boolean  bIsMethod

    String[] AllMessages

    Move false to bisMethod

    Move (lowercase(sVariable)) To sVariable

    If (sVariable<>"") Begin

      Move ("get_"+sVariable) to sVariable

      Get pAllMessages to AllMessages

      Move (SizeOfArray(AllMessages)) To iCount

      Decrement iCount

      For iMethod From 0 To iCount

        If (AllMessages[iMethod]=sVariable) Begin

          Move True To bIsMethod

          Move iCount To iMethod // stop

        End

      Loop

    End

    Function_Return bIsMethod

  End_Function

  Procedure UpdateBreakPointsGrid

    Handle  hoGrid

    Get phoBreakpointsGrid To hoGrid

    If (hoGrid) Begin

      Send LoadData Of hoGrid

    End

  End_Procedure

  //

  // Tries to find the breakpoint in the array, returns -1 if not found

  //

  Function FindBreakPointinArray String sFile Uinteger iLine Returns integer

    Integer iPos

    Integer iBreak

    Integer iCount

    tBreakPoints[] BP

    Move -1 To iPos

    Get pBreakPoints To BP

    Move (Lowercase(sFile)) To sFile

    Move (SizeOfArray(BP)) To iCount

    For iBreak from 0 To (iCount-1)

      If (lowercase(BP[iBreak].sFileName)=sFile and BP[iBreak].iLine=iLine) Begin

        Move iBreak To iPos

        Move iCount To iBreak // stop

      End

    Loop

    Function_Return iPos

  End_Function

  Procedure AddBreakPointToArray String sFile UInteger iLine

    Integer iCount

    Integer iBreak

    String  sLine

    Handle  hoEditor

    tBreakPoints[] BP

    Get FindBreakPointInArray sFile iLine To iBreak

    If (iBreak=-1) Begin

      Get pBreakPoints To BP

      Move (SizeOfArray(BP)) To iCount

      Move True   To BP[iCount].bEnabled

      Move sFile  To BP[iCount].sFileName

      Move iline  To BP[iCount].iLine

      Move false  To BP[iCount].bHasCondition

      Get phoEditor To hoEditor

      If (hoEditor) begin

        Get ComGetLine of hoEditor iLine To sLine

        Move (Rtrim(sLine)) To sLine

        Move sLine To BP[iCount].sLine

      End

      Set pBreakPoints To BP

    End

  End_Procedure

  Procedure EnableBreakPoint String sFile UInteger iLine

    Integer iBreak

    Integer retVal

    tBreakPoints[] BP

    Get FindBreakPointInArray sFile iLine To iBreak

    If (iBreak<>-1) Begin

      Get pBreakPoints To BP

      If (BP[iBreak].bEnabled=false) Begin

        Move True   To BP[iBreak].bEnabled

        Get ComSetBreakPoint sFile iLine to retVal

        Set pBreakPoints To BP

        Send UpdateBreakPointsGrid

      End

    End

  End_Procedure

  Procedure DisableBreakPoint String sFile UInteger iLine

    Integer retVal

    Integer iBreak

    tBreakPoints[] BP

    Get FindBreakPointInArray sFile iLine To iBreak

    If (iBreak<>-1) Begin

      Get pBreakPoints To BP

      If (BP[iBreak].bEnabled) Begin

        Move False   To BP[iBreak].bEnabled

        Get ComRemoveBreakPoint sFile iLine to retVal

        Set pBreakPoints To BP

        Send UpdateBreakPointsGrid

      End

    End

  End_Procedure

  Procedure RemoveBreakPointFromArray integer iPos

    Integer iCount

    tBreakPoints[] BP

    If (iPos>-1) Begin

      Get pBreakPoints To BP

      Move (SizeOfArray(BP)) To iCount

      If (iPos<iCount) Begin

        Move (RemoveFromArray(BP,iPos)) To BP

        Set pBreakPoints To BP

      End

    End

  End_Procedure

  // Sets the specified breakpoint

  Function SetBreakPoint String llfile UInteger ByRef llline Returns Boolean

    Boolean retVal

    Integer iLine

    Move llline To iLine

    Get ComSetBreakPoint llfile (&llline) to retVal

    If (retVal) Begin

      Send AddBreakPointToArray llfile iLine

      Send UpdateBreakPointsGrid

    End

    Function_Return retVal

  End_Function

  // Removes the specified breakpoint

  Function RemoveBreakPoint String llfile UInteger llline Returns Boolean

    Integer iPos

    Boolean retVal

    Get ComRemoveBreakPoint llfile llline to retVal

    If (retVal) Begin

      Get FindBreakPointInArray llfile llline To iPos

      Send RemoveBreakPointFromArray iPos

      Send UpdateBreakPointsGrid

    End

    Function_Return retVal

  End_Function

  // Introduced in vdf15.0

  // Sets the specified conditional breakpoint expression

  Function SetBreakPointCondition String llfile UInteger ByRef llline String llexpr Returns Boolean

    Boolean retVal

    Get ComSetBreakPointCondition llfile (&llline) llexpr to retVal

    If (retVal) Begin

    End

    Function_Return retVal

  End_Function

  //

  // Loads the breakpoints from the array that got loaded from a disk file.

  //

  Procedure SetBreakPointsFromArray

    Integer  iBreak

    Integer  iCount

    String   sFileName

    UInteger iLine

    Boolean  retVal

    Boolean  bEnabled

    Boolean  bIsValid

    tBreakPoints[] BP

    Get pBreakPoints To BP

    Move (SizeOfArray(BP)) To iCount

    For iBreak from 0 To (iCount-1)

      Move BP[iBreak].bEnabled  To bEnabled

      If (bEnabled) Begin

        Move BP[iBreak].sFileName To sFileName

        Move BP[iBreak].iLine     To iLine

        Get ComIsValidSourceFile sFileName To bIsValid

        If (bIsValid) Begin

          Get ComSetBreakPoint sFileName (&iLine) to retVal

        End

      End

    Loop

  End_Procedure // SetBreakPointsFromArray

  Function HasBreakPoints Returns Boolean

    Integer  iCount

    Boolean  bHasBreakPoints

    tBreakPoints[] BP

    Get pBreakPoints To BP

    Move (SizeOfArray(BP)) To iCount

    If (iCount>0) Move True To bHasBreakPoints

    Else Move False To bHasBreakPoints

    Function_Return bHasBreakPoints

  End_Function

  Procedure LoadBreakPointsFromDisk

    Boolean bExists

    Integer iVoid

    Integer iPos

    Integer iBreak

    Integer iCount

    String  sPath

    String  sBPFile

    String  sSection

    String  sKey

    String  sValue

    Handle  hoSections

    Handle  hoIni

    tBreakPoints[] BP

    Get psIdeSrcPath To sPath

    If (sPath<>"") Begin     // Only try to save if we could find a matching IdeSrc path

      Get psBPFileName To sBPFile

      Get vFolderFormat sPath To sPath

      Move (sPath+sBPFile) to sBPFile

      Get Create (RefClass(cIniFile)) To hoIni

      If (hoIni) Begin

        Set psFileName of hoIni To sBPFile

        Get Create (RefClass(Array)) To hoSections

        If (hoSections) Begin

          Send ReadSections of hoIni hoSections

          Get Item_Count of hoSections To iCount

          For iBreak from 0 To (iCount-1)

            Get Value of hoSections Item iBreak To sSection

            //Move ("Breakpoint"+trim(iBreak)) To sSection

            Get ReadString of hoIni sSection "Enabled"      "0" To BP[iBreak].bEnabled

            Get ReadString of hoIni sSection "FileName"     ""  To BP[iBreak].sFileName

            Get ReadString of hoIni sSection "Line"         "0" To BP[iBreak].iLine

            Get ReadString of hoIni sSection "Source"       ""  To BP[iBreak].sLine

            Get ReadString of hoIni sSection "HasCondition" "0" To BP[iBreak].bHasCondition

            Get ReadString of hoIni sSection "Expression"   ""  To BP[iBreak].sExpression

          Loop

          Send Destroy of hoSections

        End

        Send Destroy of hoIni

      End

      Set pBreakPoints To BP

      Send SetBreakPointsFromArray

//      Move (SizeOfArray(BP)) To iCount

    End

  End_Procedure

  Procedure SaveBreakPointsToDisk

    Boolean bExists

    Integer iVoid

    Integer iPos

    Integer iBreak

    Integer iCount

    String  sPath

    String  sBPFile

    String  sSection

    String  sKey

    String  sValue

    Handle  hoIni

    tBreakPoints[] BP

    Get psIdeSrcPath To sPath

    If (sPath<>"") Begin     // Only try to save if we could find a matching IdeSrc path

      Get psBPFileName To sBPFile

      Get vFolderFormat sPath To sPath

      Move (sPath+sBPFile) to sBPFile

      // If it exists already, then delete it.

      Get vFilePathExists sBPFile To bExists

      If (bExists) Begin

        Get vDeleteFile sBPFile To iVoid

      End

      Get Create (RefClass(cIniFile)) To hoIni

      If (hoIni) Begin

        Set psFileName of hoIni To sBPFile

        Get pBreakPoints To BP

        Move (SizeOfArray(BP)) To iCount

        For iBreak from 0 To (iCount-1)

          Move ("Breakpoint"+trim(iBreak)) To sSection

          Send WriteString of hoIni sSection "Enabled"      BP[iBreak].bEnabled

          Send WriteString of hoIni sSection "FileName"     BP[iBreak].sFileName

          Send WriteString of hoIni sSection "Line"         BP[iBreak].iLine

          Send WriteString of hoIni sSection "Source"       BP[iBreak].sLine

          Send WriteString of hoIni sSection "HasCondition" BP[iBreak].bHasCondition

          Send WriteString of hoIni sSection "Expression"   BP[iBreak].sExpression

        Loop

        Send Destroy of hoIni

        // ToDo: Remove

        //Send info_Box "saved breakpoints"

      End

    End

  End_Procedure

  // Introduced in vdf15.0

  // Occurs if there was an error evaluating a conditional breakpoint

  Procedure OnComBreakPointError String lltext

    Send Info_Box lltext "VdfSplat Info Error on conditional breakpoint"

  End_Procedure

  // Occurs after program has been successfully initialized

  Procedure OnComProgramInit

    String[] AllMessages

    Set pbProgramStarted To True

    Set pbProgramPaused  To False

    Get ComGetAllMessages To AllMessages

    Set pAllMessages To AllMessages

    Send GetAllProperties

    Send LoadBreakPointsFromDisk

  End_Procedure

  // Occurs after the program exits

  Procedure OnComProgramExit

    Boolean  bStartedFromCLI

    String[] AllMessages

    String[] AllProperties

    Set pbProgramStarted To False

    Set pbProgramPaused  To False

    Send SaveBreakPointsToDisk

    Set ApplicationFileName To ""

    Move (ResizeArray(Allmessages,0))   To AllMessages

    Move (ResizeArray(AllProperties,0)) To AllProperties

    Set pAllMessages   to AllMessages

    Set pAllProperties to AllProperties

    Get pbStartedFromCLI of ghoApplication To bStartedFromCLI

    If (bStartedFromCli) Begin

      // debug session was started from the command line.

      // Stopping the debug session normally should stop the debugger as well.

      Send Exit_Application

    End

  End_Procedure

  // Occurs if there is an error starting the program

  Procedure OnComProgramStartupError String llerrorMessage

    Set pbProgramStarted To False

    Send Info_Box llerrorMessage "start up error"

  End_Procedure

  // Occurs if there is an error initializing the program

  Procedure OnComProgramInitError String llerrorMessage

    Set pbProgramStarted To False

    Send Info_Box (llErrorMessage) "Custom Error INIT"

  End_Procedure

  Procedure SetDebuggerAsForegroundApp

    Handle  hoEditor

    Handle  hWnd

    Integer iVoid

    Get phoEditor To hoEditor

    If (hoEditor) Begin

      Get Window_Handle of hoEditor To hWnd

      If (hWnd) Begin

        Move (SetForegroundWindow(hWnd)) To iVoid

      End

    End

  End_Procedure // SetDebuggerAsForegroundApp

  //

  // Hook to be used

  // Called from OnComProgramPaused

  //

  // Occurs when the program execution is paused

  Procedure OnProgramPaused String llfile UInteger llline Boolean lllimitedBreakMode

    Handle hoEditor

    String sBreakMode

    Get phoEditor   To hoEditor

    If (hoEditor) Begin

      If lllimitedBreakMode Begin

        Move "limited Break mode" To sBreakMode

        //Else Move "Unlimited Break mode" to sBreakMode

        Send info_Box ("Pausing program\n"+sBreakMode) "VdfSplat Info"

      End

      Else Begin

        Send SetDebuggerAsForegroundApp

      End

      Send doOpenSourceFileAtLine of hoEditor llfile llline

      Send doActivateCallStack  // only displays if exists or not.

    End

  End_Procedure

  //

  // Occurs when the program execution is paused

  Procedure OnComProgramPaused String llfile UInteger llline Boolean lllimitedBreakMode

    Set pbProgramPaused  To True

    Send OnProgramPaused llfile llline lllimitedBreakMode

  End_Procedure

  // Occurs when the program execution resumes

  Procedure OnComProgramContinue

    Set pbProgramPaused  To False

  End_Procedure

  // Occurs after a change requiring views to be refreshed

  Procedure OnUpdateView String sFileName UInteger iLine

    Handle hoEditor

    Get phoEditor To hoEditor

    If (hoEditor) begin

      //Send Info_Box "OnComUpdateView" (llfile*"llline = "*trim(llline))

      Send doOpenSourceFileAtLine of hoEditor sFileName iLine

    End

  End_Procedure

  // Occurs after a change requiring views to be refreshed

  Procedure OnComUpdateView String sFileName UInteger iLine

    Send OnUpdateView sFileName iLine

  End_Procedure

  // Occurs when a new message is executed

  Procedure OnComNewMessage Integer llbSteppin

  End_Procedure

  // Occurs if an unhandled program exception is detected

  Procedure OnComUnhandledProgramException String lldescription

    Send Info_box lldescription "FATAL Error"

  End_Procedure

  // Occurs if there is an incoming request for another web app session. You can abandon the current session and switch to the new session or deny the new session and continue debugging the current session

  Procedure OnComAcceptWebAppSession Boolean ByRef llacceptNewSession

  End_Procedure

  // Occurs if there is a fatal web app error

  Procedure OnComWebAppError String lldescription

    Send Info_box lldescription "WebApp FATAL Error"

  End_Procedure

  // Occurs when a new webapp event log entry is added

  Procedure OnComWebAppLog Integer lleventId String lltext

    //Send Info_box lldescription "WebApp FATAL Error"

    Showln lleventid lltext

  End_Procedure

  Procedure doCreateCallStack

    Handle  hoParent

    Handle  hoCallStack

    Boolean bCreated

    Get phoCallStackHost To hoParent

    If (hoParent) Begin

      Get Create Of hoParent U_cCallStack To hoCallStack

      If (hoCallStack) Begin

        Set Name               Of hoCallStack To "oCallStack"

        Send CreateComObject   Of hoCallStack

        Get IsComObjectCreated Of hoCallStack To bCreated

        If (bCreated) Begin

          Send SetControlColumnWidth of hoCallStack hoCallStack

        End

      End

    End

  End_Procedure // doCreateCallStack

  Procedure doCreateWatches

    Handle  hoParent

    Handle  hoWatches

    Boolean bCreated

    Get phoWatchesHost To hoParent

    If (hoParent) Begin

      Get Create Of hoParent U_cWatches To hoWatches

      If (hoWatches) Begin

        Set Name               Of hoWatches To "oWatches"

        Send CreateComObject   Of hoWatches

        Get IsComObjectCreated Of hoWatches To bCreated

        If (bCreated) Begin

        End

      End

    End

  End_Procedure // doCreateWatches

  Procedure doCreateMessageTrace

    Handle  hoParent

    Handle  hoTrace

    Boolean bCreated

    Get phoTraceHost To hoParent

    If (hoParent) Begin

      Get Create Of hoParent U_cMessageTrace To hoTrace

      If (hoTrace) Begin

        Set Name               Of hoTrace To "oMessageTrace"

        Send CreateComObject   Of hoTrace

        Get IsComObjectCreated Of hoTrace To bCreated

        If (bCreated) Begin

        End

      End

    End

  End_Procedure // doCreateMessageTrace

  Procedure doCreateGlobalVariables

    Handle  hoParent

    Handle  hoVariables

    Boolean bCreated

    Get phoGlobalVarHost To hoParent

    If (hoParent) Begin

      Get Create Of hoParent U_cVariablesWindow To hoVariables

      If (hoVariables) Begin

        Set phoGlobalVariables To hoVariables

        Set Name               Of hoVariables To "oGlobalVariables"

        Send CreateObjectCallback of hoParent hoVariables

        Send CreateComObject   Of hoVariables

        Get IsComObjectCreated Of hoVariables To bCreated

        If (bCreated) Begin

          Set ComWindowType Of hoVariables To 1 // global

        End

      End

    End

  End_Procedure // doCreateGlobalVariables

  Procedure doCreateLocalVariables

    Handle  hoParent

    Handle  hoVariables

    Boolean bCreated

    Get phoLocalVarHost To hoParent

    If (hoParent) Begin

      Get Create Of hoParent U_cVariablesWindow To hoVariables

      If (hoVariables) Begin

        Set phoLocalVariables  To hoVariables

        Set Name               Of hoVariables To "oLocalVariables"

        Send CreateObjectCallback of hoParent hoVariables

        Send CreateComObject   Of hoVariables

        Get IsComObjectCreated Of hoVariables To bCreated

        If (bCreated) Begin

          Set ComWindowType Of hoVariables To 0 // locals

        End

      End

    End

  End_Procedure // doCreateLocalVariables

  Procedure doCreateTablesWindow

    Handle  hoParent

    Handle  hoTables

    Boolean bCreated

    Get phoTablesHost To hoParent

    If (hoParent) Begin

      Get Create Of hoParent U_cTablesWindow To hoTables

      If (hoTables) Begin

        Set Name               Of hoTables To "oTablesWindow"

        Send CreateComObject   Of hoTables

        Get IsComObjectCreated Of hoTables To bCreated

        If (bCreated) Begin

        End

      End

    End

  End_Procedure // doCreateTables

  Procedure doActivateCallStack

    Handle  hoCallStack

    Boolean bCreated

    Get phoCallStack To hoCallStack

    If (hoCallStack) Begin

      Get IsComObjectCreated Of hoCallStack To bCreated

      If (bCreated) Begin

        Send Activate of hoCallStack  // we MUST send activate to the callstack to make it display itself

      End

    End

  End_Procedure // doActivateCallStack

  Procedure DoCreateEngine

    Boolean bCreated

    Handle  hoDebugger

    Handle  hoEditor

    Send CreateComObject

    Get IsComObjectCreated to bCreated

    If (bCreated) Begin

      Move Self To hoDebugger

      Set pbEngineActive To True

      Set phoDebugger to hoDebugger

    End

    Send DoCreateCallStack

    Send DoCreateWatches

    Send DoCreateMessageTrace

    Send DoCreateGlobalVariables

    Send doCreateLocalVariables

    Send doCreateTablesWindow

  End_Procedure // DoCreateEngine

  Procedure OnCreate

    forward Send OnCreate

  End_Procedure // OnCreate

End_Class // cDebuggerEngine