The Hammer » VDF Splat

//****************************************************************************

// $Module type: Package

// $Module name: cOSVersionInfo

// $Author     : Wil van Antwerpen

// Created     : 2010-05-04

// License     : LGPL

//

// Usage       : In its most bare form you would call it to retrieve the string that

//               sums up all of the OS capabilities for your host like this:

//

//               Function HostOS Returns String

//                 Handle  hoVersionInfo

//                 String  sOSVersion

//

//                 Move "" To sOSVersion

//                 Get Create U_cOSVersionInfo To hoVersionInfo

//                 If (hoVersionInfo) Begin

//                   Get OSVersion    Of hoVersionInfo To sOSVersion

//                 End

//

//                 Function_Return sOSVersion

//               End_Function // HostOS

//

// Comment     : This package is based on the regcheck package from http://www.vdf-guidance.com

//               The OS detection logic has been extracted from there and put in here.

//               It has been rewritten in a way that makes it more versatile and easier to use.

//

//               The property peOSVersion should be used if you want to run code that depends

//               on a specific OS version.

//

//

//               Current Limitations, the code does not check for Hyper-V roles or

//               if windows is licensed, or if the Vista Version used is Ultimate or

//               Professional. For that we will need to use the GetProductInfo WinAPI

//               call. (Vista and up) Knowing the OS version is Vista is OK for now.

//

// ***********************************************************************

Use Windows

Use cOSVersionInfo.h

use cWinKernEx.h      // Package from the cWindowsEx project

Use cSystemInfo.pkg

Class cOSVersionInfo Is a cObject

  Procedure Construct_Object

    Forward Send Construct_Object

    // The next properties return info about the Operating System.

    // They are set by the procedure DoGetVersionInfo, which is send from

    // the automatically invoked DoCheckWindowsVersion.

    //

    // Identifies the major version number of the operating system.

    // For example, for Windows NT version 3.51, the major version number is 3;

    // and for Windows NT version 4.0, the major version number is 4.

    Property Integer piMajorVersion            0

    // Identifies the minor version number of the operating system. For example,

    // for Windows NT version 3.51, the minor version number is 51; and for

    // Windows NT version 4.0, the minor version number is 0.

    // For Windows 95, dwMinorVersion is zero.

    // For Windows 98, dwMinorVersion is greater than zero.

    Property Integer piMinorVersion            0

    // Identifies the build number of the operating system.

    Property Integer piBuildNumber             0

    // Identifies the operating system platform. This member can be one of the

    // following values:

    // CP_VER_PLATFORM_WIN32s Win32s on Windows 3.1.

    // CP_VER_PLATFORM_WIN32_WINDOWS Win32 on Windows 95 or Windows 98.

    // CP_VER_PLATFORM_WIN32_NT Win32 on Windows NT.

    Property Integer piPlatFormId              0

    // Windows NT: Contains a string, such as "Service Pack 3",

    // that indicates the latest Service Pack installed on the system. If no

    // Service Pack has been installed, the string is empty.

    // Windows 95: Contains a null-terminated string that provides arbitrary

    // additional information about the operating system.

    Property String psCSDVersion               ''

    // PHvW 20/04/2002 14:37

    // Identifies the major version number of the latest Service Pack installed

    // on the system. For example, for Service Pack 3, the major version

    // number is 3. If no Service Pack has been installed, the value is zero.

    Property Integer piServicePackMajor        0

    // PHvW 20/04/2002 14:37

    // Identifies the minor version number of the latest Service Pack installed

    // on the system. For example, for Service Pack 3, the minor version

    // number is 0.

    Property Integer piServicePackMinor        0

    // PHvW 20/04/2002 14:37

    // A set of bit flags that identify the product suites available on the system.

    // This member can be a combination of the following values. (see msdn)

    Property Integer piSuiteMask               0

    //

    // The psSuite string only contains features which can be enabled or not, so it is NOT

    // a direct mapping to piSuiteMask. An example of this is if you are in a remote desktop

    // session or not.

    Property String  psSuite                   ""

    // The Edition string contains specific details about the platform that cannot be

    // enabled as a role. So "Home" Edition or "Datacenter" edition are good examples.

    // R2 is a peOSVersion

    Property String  psEdition                 ""

    // PHvW 20/04/2002 14:37

    // Indicates additional information about the system. This member can be

    // one of the following values. VER_NT_WORKSTATION, VER_NT_SERVER, VER_NT_DOMAIN_CONTROLLER

    Property Integer piProductType             0

    // PHvW 22/04/2002 17:48

    // Contains which version of windows is running as a text.

    // If it can not sort it out it will be CS_OSVERSION_UNKNOWN (="Windows Version UNKNOWN")

    Property String  psOSVersion               CS_OSVERSION_UNKNOWN

    Property Integer peOSVersion               CE_OSVERSION_UNKNOWN

    // PHvW 22/04/2002 17:50

    // Running windows version is a server version

    Property Boolean pbNTServer                False

    // PHvW 22/04/2002 17:50

    // Running on a Windows HOME version. That is Windows ME and Windows XP Home

    // Both are not recommended platforms for business (networking is limited).

    // So not for vdf.

    Property Boolean pbWindowsHome             False

    // pbX64 is set to true if your host OS is x64

    Property Boolean pbX64                     False

    // pbRemoteDesktop is set to true if your application currently runs under a remote desktop session

    Property Boolean pbRemoteDesktop           False

    Property Boolean pbAdminRights             False

  End_Procedure // Construct_Object

  // Procedure sets OS info properties defined in this class

  // The static variables and the structure used are declared in prnt_dlg.pkg.

  Procedure DoGetVersionInfo

    Integer iRetval

    String  sOSVersionInfo sCSDVersion

    Pointer pOSVersionInfo

    FillType _OSVERSIONINFO With 0 To sOSVersionInfo

    Put _OSVERSIONINFO_Size To sOSVersionInfo At _OSVERSIONINFO.dwOSVersionInfoSize

    GetAddress Of sOSVersionInfo To pOSVersionInfo

    Move (GetVersionEx(pOSVersionInfo)) To iRetval // Function in Prnt_Dlg.pkg

    Indicate Err False

    If Not iRetval Begin

      Error 500 csOsVersionNumberCouldNotRetrieved

      Procedure_Return

    End

    GetBuff From sOSVersionInfo At _OSVERSIONINFO.dwMajorVersion      To iRetval

    Set piMajorVersion To iRetval

    GetBuff From sOSVersionInfo At _OSVERSIONINFO.dwMinorVersion      To iRetval

    Set piMinorVersion To iRetval

    GetBuff From sOSVersionInfo At _OSVERSIONINFO.dwPlatformID        To iRetval

    Set piPlatFormId To iRetval

    GetBuff_String From sOSVersionInfo At _OSVERSIONINFO.szCSDVersion To sCSDVersion

    Move (Cstring(sCSDVersion)) To sCSDVersion

    Set psCSDVersion To (Trim(sCSDVersion))

  End_Procedure // DoGetVersionInfo

  Procedure DoGetVersionInfoEx

    Integer iRetval

    String  sOSVersionInfoEx sCSDVersion

    Pointer pOSVersionInfoEx

    FillType _OSVERSIONINFOEX With 0 To sOSVersionInfoEX

    Put _OSVERSIONINFOEX_Size To sOSVersionInfoEx At _OSVERSIONINFOEX.dwOSVersionInfoSize

    GetAddress Of sOSVersionInfoEX To pOSVersionInfoEX

    Move (GetVersionEx(pOSVersionInfoEx)) To iRetval

    Indicate Err False

    If Not iRetval Begin

      Error 500 csOsVersionNumberCouldNotRetrieved

      Procedure_Return

    End

    GetBuff From sOSVersionInfoEx At _OSVERSIONINFOEX.dwMajorVersion      To iRetval

    Set piMajorVersion To iRetval

    GetBuff From sOSVersionInfoEx At _OSVERSIONINFOEX.dwMinorVersion      To iRetval

    Set piMinorVersion To iRetval

    GetBuff From sOSVersionInfoEx At _OSVERSIONINFOEX.dwBuildNumber       To iRetval

    Set piBuildNumber To iRetval

    GetBuff From sOSVersionInfoEx At _OSVERSIONINFOEX.dwPlatformID        To iRetval

    Set piPlatFormId To iRetval

    GetBuff_String From sOSVersionInfoEx At _OSVERSIONINFOEX.szCSDVersion To sCSDVersion

    Move (Cstring(sCSDVersion)) To sCSDVersion

    Set psCSDVersion To (Trim(sCSDVersion))

    GetBuff From sOSVersionInfoEx At _OSVERSIONINFOEX.wServicePackMajor   To iRetval

    Set piServicePackMajor To iRetval

    GetBuff From sOSVersionInfoEx At _OSVERSIONINFOEX.wServicePackMinor   To iRetval

    Set piServicePackMinor To iRetval

    GetBuff From sOSVersionInfoEx At _OSVERSIONINFOEX.wSuiteMask           To iRetval

    Set piSuiteMask To iRetval

    GetBuff From sOSVersionInfoEx At _OSVERSIONINFOEX.wProductType        To iRetval

    Set piProductType To iRetval

  End_Procedure // DoGetVersionInfoEx

  //

  // Determines processor architecture and windows editions

  //

  Procedure RetrieveOSEdition Integer iMajorVersion Integer iMinorVersion Integer iSuiteMask

    Handle  hoSystemInfo

    Integer iProcessorArchitecture

    String  sEdition

    Move PROCESSOR_ARCHITECTURE_UNKNOWN To iProcessorArchitecture

    // Min version is XP

    Get Create U_cSystemInfo To hoSystemInfo

    If (hoSystemInfo) Begin

      Get piProcessorArchitecture Of hoSystemInfo To iProcessorArchitecture

      If (iProcessorArchitecture=PROCESSOR_ARCHITECTURE_AMD64) Begin

          Set pbX64 To True

      End

    End

    If (GetSystemMetrics(SM_MEDIACENTER)<>0) Begin

      Move CS_OS_MCE To sEdition

    End

    If (GetSystemMetrics(SM_STARTER)<>0) Begin

      Move CS_OS_STARTER To sEdition

    End

    If (GetSystemMetrics(SM_TABLETPC)<>0) Begin

      Move CS_OS_TABLETPC To sEdition

    End

    Case Begin

      Case (iSuiteMask Iand Ver_Suite_Personal)

        Move CS_OS_HOME To sEdition

        Set pbWindowsHome To True

        Case Break

      Case (iSuiteMask Iand Ver_Suite_EmbeddedNT)

        Move CS_OS_EMBEDDED To sEdition

        Case Break

      Case (iSuiteMask Iand Ver_Suite_Blade)

        Move CS_OS_WEB To sEdition

        Case Break

      Case (iSuiteMask Iand Ver_Suite_Datacenter)

        Move CS_OS_DATACENTER To sEdition

        Case Break

      Case (iSuiteMask Iand Ver_Suite_Enterprise)

        Move CS_OS_ENTERPRISE To sEdition

        Case Break

    Case End

    If (sEdition<>"") Begin

      // Microsoft had the habit of adding "Edition" behind its edition identifier string in the past

      If (iMajorVersion=5 and iMinorVersion>=1) Move (sEdition*CS_OS_EDITION) To sEdition

    End

    Set psEdition To sEdition

  End_Procedure // RetrieveOSEdition

  //

  // Determine the psSuite string and try to find out features such as if you are running in an

  // remote Desktop session, or if the user has administrator rights

  //

  Procedure RetrieveOSFeatures Integer iMajorVersion Integer iMinorVersion

    String  sSuite

    Move "" To sSuite

    If (GetSystemMetrics(SM_REMOTESESSION)<>0) Begin

      Move (sSuite+CS_OS_REMOTESESSION) To sSuite

      Set pbRemoteDesktop To True

    End

    If (iMajorVersion>5 or (iMajorVersion>=5 and iMinorVersion>=1)) Begin

      // Check only win2000 and up

      If (IsAdministrator()) Begin

        If (sSuite<>"") Move (sSuite+", ") To sSuite

        Move (sSuite+CS_OS_ISADMINISTRATOR) To sSuite

        Set pbAdminRights To True

      End

    End

    Set psSuite   To sSuite

  End_Procedure // RetrieveOSFeatures

  //

  // This sets the psOsVersion and peOSVersion properties based on what has been found.

  // The psOSversion should not be used to identify the base OS, use peOSVersion for that.

  //

  Procedure RetrieveOSVersion

    Integer iMajorVersion

    Integer iMinorVersion

    Integer iBuildNumber

    Integer iPlatFormId

    String  sCSDVersion

    String  sOSVersion

    Integer iServicePackMajor

    Integer iServicePackMinor

    Integer iSuiteMask

    Integer iProductType

    Boolean bServerR2

    Move False To bServerR2

    Get piMajorVersion     To iMajorVersion

    Get piMinorVersion     To iMinorVersion

    Get piBuildNumber      To iBuildNumber

    Get piPlatFormId       To iPlatFormId

    Get psCSDVersion       To sCSDVersion

    Get piServicePackMajor To iServicePackMajor

    Get piServicePackMinor To iServicePackMinor

    Get piSuiteMask        To iSuiteMask

    Get piProductType      To iProductType

    If (iMajorVersion>5 or (iMajorVersion>=5 and iMinorVersion>=1)) Begin

      // Set psEdition and check x64 capabilities

      Send RetrieveOSEdition iMajorVersion iMinorVersion iSuiteMask

      If (GetSystemMetrics(SM_SERVERR2)<>0) Begin

        Move True To bServerR2

      End

    End

    If (iMajorVersion>=5) Begin

      Send RetrieveOSFeatures iMajorVersion iMinorVersion

    End

    Case Begin

      Case (iMajorVersion = 3)

        Set psOSVersion To CS_OSVERSION_NT35

        Set peOSVersion To CE_OSVERSION_NT35

        Case Break

      Case (iMajorVersion = 4)                      // Windows 9X Series and Win NT 40

        If (iPlatFormId = CP_VER_PLATFORM_WIN32_WINDOWS) Begin    // Then Windows 95 or 98...

          Case Begin

            Case (iMinorVersion = 0)

              Set psOSVersion To CS_OSVERSION_WIN95

              Set peOSVersion To CE_OSVERSION_WIN95

              Case Break

            Case (iMinorVersion = 10)

              Set psOSVersion To CS_OSVERSION_WIN98

              Set peOSVersion To CE_OSVERSION_WIN98

              Case Break

            Case (iMinorVersion = 90)

              Set psOSVersion   To CS_OSVERSION_WINME

              Set peOSVersion   To CE_OSVERSION_WINME

              Set pbWindowsHome To True

              Case Break

          Case End

        End

        Else Begin

          Case Begin

            Case (iProductType = VER_NT_WORKSTATION)

              Set psOSVersion To CS_OSVERSION_NT4WKS

              Set peOSVersion To CE_OSVERSION_NT4WKS

              Case Break

            Case (iProductType = VER_NT_DOMAIN_CONTROLLER)

              Set psOSVersion To CS_OSVERSION_NT4SRV

              Set peOSVersion To CE_OSVERSION_NT4SRV

              Set pbNTServer  To True

              Case Break

          Case End

        End

        Case Break

      Case (iMajorVersion = 5)                      // Windows NT2k Series

        Case Begin

          Case (iMinorVersion = 0)                  // Windows 2000

            If (iProductType = VER_NT_WORKSTATION) Begin

              Set psOSVersion To  CS_OSVERSION_W2K

              Set peOSVersion To  CE_OSVERSION_W2K

            End

            Else Begin

              Set psOSVersion To  CS_OSVERSION_W2KSRV

              Set peOSVersion To  CE_OSVERSION_W2KSRV

              Set pbNTServer  To True

            End

            Case Break

          Case (iMinorVersion = 1)                  // XP (and NOT 2003 server)

            Case Begin

              Case (iSuiteMask Iand Ver_Suite_Personal)

                Set psOSVersion   To CS_OSVERSION_WXP

                Set peOSVersion   To CE_OSVERSION_WXP

                Set pbWindowsHome To True

                Case Break

              Case (iProductType = VER_NT_WORKSTATION)

                If (psEdition(Self)="") Move CS_OSVERSION_WXPPRO To sOSVersion

                Else Move CS_OSVERSION_WXP To sOSVersion

                Set psOSVersion To  sOSVersion

                Set peOSVersion To  CE_OSVERSION_WXP

                Case Break

            Case End

            Case Break

          Case (iMinorVersion = 2)

            Case Begin

              // WXP x64

              // (OSVERSIONINFOEX.wProductType == VER_NT_WORKSTATION) && (SYSTEM_INFO.wProcessorArchitecture==PROCESSOR_ARCHITECTURE_AMD64)

              Case (iProductType = VER_NT_WORKSTATION and pbX64(Self)=True)

                Set psOSversion To CS_OSVERSION_WXPX64

                Set peOSVersion To CE_OSVERSION_WXP

                Case Break

              Case (bServerR2=false)

                Set psOSVersion To CS_OSVERSION_2K3

                Set peOSVersion To CE_OSVERSION_2K3

                Set pbNTServer  To True

                Case Break

              Case (iSuiteMask Iand VER_SUITE_WH_SERVER)

                Set psOSVersion To CS_OSVERSION_HMESRV

                Set peOSVersion To CE_OSVERSION_2K3

                Set pbNTServer  To True

                Case Break

              Case (bServerR2=True)

                Set psOSVersion To CS_OSVERSION_2K3R2

                Set peOSVersion To CE_OSVERSION_2K3R2

                Set pbNTServer  To True

                Case Break

            Case End

            Case Break

        Case End

        Case Break

      Case (iMajorVersion = 6)   // Windows Vista / Home Server Series / Windows 7 & Windows 8

        Case Begin

          Case (iMinorVersion = 0)                  // Windows Vista

            Case Begin

              Case (iSuiteMask Iand Ver_Suite_Personal)

                Set psOSVersion   To CS_OSVERSION_VISTA

                Set peOSVersion   To CE_OSVERSION_VISTA

                Set pbWindowsHome To True

                Case Break

              Case (iProductType = VER_NT_WORKSTATION)

                Set psOSVersion To  CS_OSVERSION_VISTA

                Set peOSVersion To  CE_OSVERSION_VISTA

                Case Break

              Case (iProductType <> VER_NT_WORKSTATION)

                Set psOSVersion to  CS_OSVERSION_2K8

                Set peOSVersion to  CE_OSVERSION_2K8

                Set pbNTServer  To True

                Case Break

            Case End

            Case Break

          Case (iMinorVersion = 1)                  // Windows 7

            Case Begin

              Case (iProductType = VER_NT_WORKSTATION)

                Set psOSVersion To  CS_OSVERSION_W7

                Set peOSVersion To  CE_OSVERSION_W7

                Case Break

              Case (iProductType <> VER_NT_WORKSTATION)

                Set psOSVersion to  CS_OSVERSION_2K8R2

                Set peOSVersion to  CE_OSVERSION_2K8R2

                Set pbNTServer  To True

                Case Break

            Case End

            Case Break

          Case (iMinorVersion = 2)                  // Windows 8 and Windows 2012

            Case Begin

              Case (iProductType = VER_NT_WORKSTATION)

                Set psOSVersion To  CS_OSVERSION_W8

                Set peOSVersion To  CE_OSVERSION_W8

                Case Break

              Case (iProductType <> VER_NT_WORKSTATION)

                Set psOSVersion to  CS_OSVERSION_2K12

                Set peOSVersion to  CE_OSVERSION_2K12

                Set pbNTServer  To True

                Case Break

            Case End

            Case Break

        Case End

        Case Break

    Case End

  End_Procedure // RetrieveOSVersion

  //

  // Returns the full OS version name including service pack level as a string

  //

  // If the version is unknown to the package, it will list the major and

  // minor version appended the string returned in the format " (major.minor)"

  //

  Function OSVersion Returns String

    Integer iServicePack

    Integer iBuildNumber

    Integer iMajor

    Integer iMinor

    String  sOSVersion

    String  sSuite

    String  sEdition

    String  sCSDVersion

    Get psOSVersion        To sOSVersion

    If (sOSVersion=CS_OSVERSION_UNKNOWN) Begin

      Get piMajorVersion To iMajor

      Get piMinorVersion To iMinor

      Move (sOSVersion+" ("+trim(iMajor)+"."+trim(iMinor)+")") To sOSVersion

    End

    Else Begin

      Get psEdition To sEdition

      If (sEdition<>"") Begin

        Move (sOSVersion*sEdition) To sOSVersion

      End

      Get piBuildNumber To iBuildNumber

      If (iBuildNumber<>0) Begin

        Move (sOSVersion+" Build "+trim(iBuildNumber)+" ") To sOSVersion

      End

      Get piServicePackMajor To iServicePack

      If (iServicePack>0) Begin

        Get psCSDVersion To sCSDVersion

        Move (sOSVersion+sCSDVersion) To sOSVersion

      End

    End

    If (pbX64(Self)) Begin

      Move (sOSVersion * "x64") To sOSVersion

    End

    Get psSuite To sSuite

    If (sSuite<>"") Begin

      Move (sOSVersion*"("+sSuite+")") To sOSVersion

    End

    Function_Return sOSVersion

  End_Function // OSVersion

  // This is the main procedure that checks which Windows version

  // is running and calls the appropiate procedure above.

  // SETS PUBLIC OS PROPERTIES

  // Gets called by End_Construct_Object below.

  Procedure DoCheckWindowsVersion

    Indicate Err False

    Send DoGetVersionInfo

    If ((piMajorVersion (Self)) > 4) Begin

      Indicate Err False

      Send DoGetVersionInfoEx

    End

    If Not (Err) Begin

      Send RetrieveOSVersion

    End

  End_Procedure // DoCheckWindowsVersion

  // Automatically sets all class properties upon creation.

  Procedure End_Construct_Object

    Forward Send End_Construct_Object

    Send DoCheckWindowsVersion

  End_Procedure // End_Construct_Object

End_Class // cOSVersionInfo