The Hammer » VDF Splat

//TH-Header

//*****************************************************************************************

// Copyright (c)  2013 Antwise Solutions

// All rights reserved.

//

// $FileName    : Vdfdbg.vw

// $ProjectName : Splat ! Vdf Debugger

// $Authors     : Wil van Antwerpen

// $Created     : 12.14.2013  23:42

// $Type        : GPLv2

//

// Contents:

// The view that hosts the various debugger controls and the codemax editor.

// Pretty much everything in here gets loaded dynamically so that we can load

// the debugger engine for the VDF version that we need.

//

//*****************************************************************************************

//TH-RevisionStart

//TH-RevisionEnd

Use Windows.pkg

Use DFClient.pkg

Use vWin32fh.pkg

Use cSplitterContainer.pkg

Use cDebuggerEngine.pkg

Use cSplatCodeMax.pkg

Use cCJGrid.pkg

Use cCJGridColumn.pkg

//Use cComCDACTreeListCtl.pkg

Class cBPOpenFileUnderCJMenuItem is a cCJMenuItem

  Procedure Construct_Object

    Forward Send Construct_Object

    Set psCaption       To "&Open File"

    Set psToolTip       To "Open file at selected breakpoint"

    Set psImage         To "ActionOpen.ico"

  End_Procedure

  Procedure OnExecute Variant vCommandBarControl

    Handle  hoGrid

    Handle  hoEditor

    Integer iLine

    String  sFileName

    Get phoBreakPointsGrid To hoGrid

    If (hoGrid) Begin

      Get SelectedRowValue Of (oFileNameColumn(hoGrid)) To sFileName

      Get SelectedRowValue Of (oLineColumn(hoGrid))     To iLine

      If (sFileName<>"" and iLine<>0) Begin

        Get phoEditor To hoEditor

        If (hoEditor) begin

          Send doOpenSourceFileAtLine of hoEditor sFileName iLine

        End

      End

    End

  End_Procedure

End_Class

Class cBPEnableBreakPointCJMenuItem is a cCJMenuItem

  Procedure Construct_Object

    Forward Send Construct_Object

    Set psCaption       To "&Enable Breakpoint"

    Set psToolTip       To "Enable Breakpoint for the selected line"

    //Set psImage         To "ActionOpen.ico"

  End_Procedure

  Procedure OnExecute Variant vCommandBarControl

    Handle  hoGrid

    Handle  hoDebugger

    Integer iLine

    String  sFileName

    Get phoBreakPointsGrid To hoGrid

    If (hoGrid) Begin

      Get SelectedRowValue Of (oFileNameColumn(hoGrid)) To sFileName

      Get SelectedRowValue Of (oLineColumn(hoGrid))     To iLine

      If (sFileName<>"" and iLine<>0) Begin

        Get phoDebugger to hoDebugger

        If (hoDebugger) begin

          Send EnableBreakpoint of hoDebugger sFileName iLine

        End

      End

    End

  End_Procedure

End_Class

Class cBPDisableBreakPointCJMenuItem is a cCJMenuItem

  Procedure Construct_Object

    Forward Send Construct_Object

    Set psCaption       To "&Disable Breakpoint"

    Set psToolTip       To "Disable Breakpoint for the selected line"

//    Set psImage         To "ActionOpen.ico"

  End_Procedure

  Procedure OnExecute Variant vCommandBarControl

    Handle  hoGrid

    Handle  hoDebugger

    Integer iLine

    String  sFileName

    Get phoBreakPointsGrid To hoGrid

    If (hoGrid) Begin

      Get SelectedRowValue Of (oFileNameColumn(hoGrid)) To sFileName

      Get SelectedRowValue Of (oLineColumn(hoGrid))     To iLine

      If (sFileName<>"" and iLine<>0) Begin

        Get phoDebugger to hoDebugger

        If (hoDebugger) begin

          Send DisableBreakpoint of hoDebugger sFileName iLine

        End

      End

    End

  End_Procedure

End_Class

Class cBreakPointsGridContextMenu Is a cCJContextMenu

    Procedure Construct_Object

      Forward Send Construct_Object

      Object oOpenFileUnderBreakPointMenuItem is a cBPOpenFileUnderCJMenuItem

      End_Object

      Object oAddBreakpoint is a cCJAddBreakpointMenuItem

      End_Object

      Object oRemoveBreakPoint is a cCJRemoveBreakpointMenuItem

      End_Object

      Object oEnableBreakPoint is a cBPEnableBreakPointCJMenuItem

      End_Object

      Object oDisableBreakPoint is a cBPDisableBreakPointCJMenuItem

      End_Object

    End_Procedure // Construct_Object

End_Class // cBreakPointsGridContextMenu

Deferred_View Activate_oVdfdbg for ;

Object oVdfdbg is a dbView

    Set Border_Style to Border_Thick

    Set Size to 346 469

    Set Location to 3 4

    Set Maximize_Icon to True

    Set phoDebuggerHost To Self

    Object oDebugSplitterContainer is a cSplitterContainer

      Set pbSplitVertical to False

      Set piSplitterLocation to 200

      Object oEditorSplitter is a cSplitterContainerChild

        Object oCodeMax is a cSplatCodeMax

          Set Size to 188 459

          Set Location to 6 6

          Set peAnchors to anAll

          Set phoEditor To Self

            Procedure OnCreate

              Variant vImageList

              Boolean bCreated

              Handle  hoLanguage

              Forward Send OnCreate

              // ToDo: Set the ActiveX properties here...

              Get ComImageList  To vImageList

              //Set ComHImageList 0  // OLE_HANDLE value

            End_Procedure

          Embed_ActiveX_Resource

          6AMAAAgAAgAAAAAACAACAAAAAAAAAQEBAAAAAQEBAQAAAQAAAAAAAAAAAAAAAAHpAwAAAQEBAAEBAAEEAP//////////////////////////////////////////QwBv

          AHUAcgBpAGUAcgAgAE4AZQB3AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAsAAAAAAAAA/////wAAAAAAAAABAAAACgAAAAEAAf//////

          ////AAAAAAABAAAAAQAAAE0uAAB2FwAA.

          End_Embed_ActiveX_Resource

        End_Object

      End_Object

      Object oDebugPanelsSplitter is a cSplitterContainerChild

        Object oDebug_TD is a TabDialog

          Set Size to 135 381

          Set Location to 4 6

          Set peAnchors to anAll

          Object oCallStack_TP is a TabPage

            Set Label to "Call Stack"

            Object oCallStackContainer is a Container3d

              Set Size to 131 377

              Set Location to 2 2

              Set peAnchors to anAll

              Set Border_Style to Border_StaticEdge

              Set phoCallStackHost To Self

              Procedure CreateObjectCallback Handle hoObject

                Handle hoCallStack

                If (hoObject) Begin

                  Get phoCallStack To hoCallStack

                  If (hoObject=hoCallStack) Begin

                    Set Size                     Of hoCallStack To 118 361

                    Set Location                 Of hoCallStack To 9 5

                    Set Label_Justification_Mode Of hoCallStack To JMode_Top

                    Set Label_Col_Offset         Of hoCallStack To 0

                    Set Label                    Of hoCallStack To "Call Stack"

                    Set peAnchors                Of hoCallStack To anAll

                  End

                End

              End_Procedure // CreateObjectCallback

              Procedure SetControlColumnWidth handle hoObject

                Handle hoCallStack

                If (hoObject) Begin

                  Get phoCallStack To hoCallStack

                  If (hoObject=hoCallStack) Begin

                    Set ComObjectColumnWidth     Of hoCallStack To 200

                    Set ComMessageColumnWidth    Of hoCallStack To 400

                  End

                End

              End_Procedure

              //Procedure RepaintTabPage

              //  Handle hWindow hVoid

              //  Get Window_Handle To hWindow

              //  If hWindow Move (InvalidateRect(hWindow,0,True)) To hVoid

              //End_Procedure // RepaintTabPage

            End_Object

          End_Object

          Object oWatches_TP is a TabPage

            Set Label to "Watches"

            Object oWatchesContainer is a Container3d

              Set Size to 131 377

              Set Location to 2 2

              Set peAnchors to anAll

              Set Border_Style to Border_StaticEdge

              Set phoWatchesHost To Self

              Procedure CreateObjectCallback Handle hoObject

                Handle hoWatches

                If (hoObject) Begin

                  Get phoWatches To hoWatches

                  If (hoObject=hoWatches) Begin

                    Set Size                     Of hoWatches To 118 361

                    Set Location                 Of hoWatches To 9 6

                    Set peAnchors                Of hoWatches To anAll

                  End

                End

              End_Procedure // CreateObjectCallback

            End_Object

          End_Object

          Object oTrace_TP is a TabPage

            Set Label to "Trace"

            Object oTraceContainer is a Container3d

              Set Size to 131 377

              Set Location to 2 2

              Set peAnchors to anAll

              Set Border_Style to Border_StaticEdge

              Set phoTraceHost To Self

              Procedure CreateObjectCallback Handle hoObject

                Handle hoTrace

                If (hoObject) Begin

                  Get phoTrace To hoTrace

                  If (hoObject=hoTrace) Begin

                    Set Size                     Of hoTrace To 118 359

                    Set Location                 Of hoTrace To 9 6

                    Set Label                    Of hoTrace To "Trace"

                    Set peAnchors                Of hoTrace To anAll

                  End

                End

              End_Procedure // CreateObjectCallback

            End_Object

          End_Object

          //Object oDACTreelist_TP is a TabPage

          //  Set Label to "DACTreeList (not used)"

          //  // I do not think we are going to use this one.

          //  Object oComCDACTreeListCtl1 is a cComCDACTreeListCtl

          //    Set Size to 100 100

          //    Set Location to 10 35

          //

          //      Procedure OnCreate

          //          Forward Send OnCreate

          //          // ToDo: Set the ActiveX properties here...

          //      End_Procedure

          //

          //  End_Object

          //End_Object

          Object oGlobalVariables_TP is a TabPage

            Set Label to "Global Variables"

            Object oGlobalVarContainer is a Container3d

              Set Size to 131 377

              Set Location to 2 2

              Set peAnchors to anAll

              Set Border_Style to Border_StaticEdge

              Set phoGlobalVarHost To Self

              Procedure CreateObjectCallback Handle hoObject

                Handle hoGlobalVar

                If (hoObject) Begin

                  Get phoGlobalVariables To hoGlobalVar

                  If (hoObject=hoGlobalVar) Begin

                    Set Size                     Of hoGlobalVar To 118 359

                    Set Location                 Of hoGlobalVar To 8 8

                    Set peAnchors                Of hoGlobalVar To anAll

                  End

                End

              End_Procedure // CreateObjectCallback

            End_Object

          End_Object

          Object oLocalVariables_TP is a TabPage

            Set Label to "Local Variables"

            Object oLocalVarContainer is a Container3d

              Set Size to 131 377

              Set Location to 2 2

              Set peAnchors to anAll

              Set Border_Style to Border_StaticEdge

              Set phoLocalVarHost To Self

              Procedure CreateObjectCallback Handle hoObject

                Handle hoLocalVar

                If (hoObject) Begin

                  Get phoLocalVariables To hoLocalVar

                  If (hoObject=hoLocalVar) Begin

                    Set Size                     Of hoLocalVar To 118 359

                    Set Location                 Of hoLocalVar To 8 8

                    Set peAnchors                Of hoLocalVar To anAll

                  End

                End

              End_Procedure // CreateObjectCallback

            End_Object

          End_Object

          Object oTables_TP is a TabPage

            Set Label to "Tables"

            Object oTablesContainer is a Container3d

              Set Size to 131 377

              Set Location to 2 2

              Set peAnchors to anAll

              Set Border_Style to Border_StaticEdge

              Set phoTablesHost To Self

              Procedure CreateObjectCallback Handle hoObject

                Handle hoTables

                If (hoObject) Begin

                  Get phoTablesWindow To hoTables

                  If (hoObject=hoTables) Begin

                    Set Size                     Of hoTables To 118 363

                    Set Location                 Of hoTables To 7 6

                    Set peAnchors                Of hoTables To anAll

                  End

                End

              End_Procedure // CreateObjectCallback

            End_Object

          End_Object

          Object oBreakpoints_TP is a TabPage

            Set Label to "Breakpoints"

            Object oBreakPointsContainer is a Container3d

              Set Size to 131 377

              Set Location to 2 2

              Set peAnchors to anAll

              Set Border_Style to Border_StaticEdge

              Object oBreakpointsGrid is a cCJGrid

                Set Size to 112 282

                Set Location to 6 10

                Set peAnchors to anAll

                Set pbReadOnly to True

                Set phoBreakpointsGrid To Self

                Object oBPContextMenu Is a cBreakPointsGridContextMenu

                End_Object

                Set phoContextMenu To oBPContextMenu

                // Need to move to subclass for this technique, maybe later.

                //Function CreateContextMenu Returns Handle

                //  Handle hoMenu

                //

                //  Get Create (RefClass(cBreakPointsGridContextMenu)) To hoMenu

                //  If (hoMenu) Begin

                //    Set Name Of hoMenu To "oBPContextMenu"

                //  End

                //  Function_Return hoMenu

                //End_Function

                Object oEnabledColumn is a cCJGridColumn

                  Set piWidth to 57

                  Set psCaption to "Active"

                  Set pbCheckbox to True

                  Set pbResizable to False

                End_Object

                Object oLineColumn is a cCJGridColumn

                  Set piWidth to 85

                  Set psCaption to "Line"

                  Set peDataType to Mask_Numeric_Window

                  Set pbResizable to False

                End_Object

                Object oFileNameColumn is a cCJGridColumn

                  Set piWidth to 351

                  Set psCaption to "File"

                End_Object

                //

                // Procedure ComSetCaretPos Integer llLine Integer llCol

                //

                // Procedure ComSelectLine Integer llLine Boolean llMakeVisible

                Procedure LoadData

                  Handle  hoDataSource

                  Handle  hoDebug

                  Boolean bFound

                  Boolean bIsCreated

                  Integer iBreak

                  Integer iCount

                  Integer iRows

                  Integer iActive

                  Integer iLine

                  Integer iFile

                  tDataSourceRow[] TheData

                  tBreakPoints[] BP

                  Get phoDataSource to hoDataSource

                  Get phoDebugger   to hoDebug

                  // Get the datasource indexes of the various columns

                  Get piColumnId of oEnabledColumn  to iActive

                  Get piColumnId of oLineColumn     to iLine

                  Get piColumnId of oFileNameColumn to iFile

                  // Load all data into the datasource array

                  If (hoDebug) Begin

                    Get pBreakPoints of hoDebug To BP

                  End

                  Move (SizeOfArray(BP)) To iCount

                  For iBreak from 0 To (iCount-1)

                    // BP[iBreak].bHasCondition

                    // BP[iBreak].sExpression

                    //If (BP[iBreak].bEnabled) Move "Y" To TheData[iRows].sValue[iActive]

                    //Else Move "N" To TheData[iRows].sValue[iActive]

                    Move BP[iBreak].bEnabled  To TheData[iRows].sValue[iActive]

                    Move BP[iBreak].iLine     To TheData[iRows].sValue[iLine]

                    Move BP[iBreak].sFileName To TheData[iRows].sValue[iFile]

                    Increment iRows

                  Loop

                  Get IsComObjectCreated To bIsCreated

                  If (bIsCreated) Begin

                    // Initialize Grid with new data

                    Send InitializeData TheData

                    Send MovetoFirstRow

                  End

                End_Procedure

              End_Object

              Object oButton3 is a Button

                Set Size to 14 61

                Set Location to 57 310

                Set Label to "add breakpoint"

                Set peAnchors to anTopRight

                Procedure OnClick

                  Integer iLine

                  String  sFileName

                  Boolean bSuccess

                  Handle  hoDebugger

                  Handle  hoEditor

                  Get phoDebugger to hoDebugger

                  Get phoEditor   to hoEditor

                  If (hoDebugger<>0 and hoEditor<>0) Begin

                    Get psFileName    of hoEditor to sFileName

                    Get piCurrentLine of hoEditor to iLine

                    If (sFileName<>"" and iLine<>0) Begin

                      Get SetBreakPoint of hoDebugger sFileName (&iLine) to bSuccess

                      Send info_box ("Set breakpoint at line"*trim(iLine)*"success="*trim(bSuccess))

                      //Send ComSetMarginImages iLine 1

                    End

                  End

          // in codemax

          //    // turns on/off margin images for a specific line

          //    Procedure ComSetMarginImages Integer llLine UChar llImages

          //

          //    // sets the line margin images

          //    Procedure Set ComHImageList OLE_HANDLE value

          //

          //    // sets the line margin images

          //    Function ComHImageList Returns OLE_HANDLE

          //    // Returns the first line number with the specified margin images

          //    Function ComFindLineMatchingMarginImages Integer llStartLine UChar llImages Returns Integer

          // in debugger

          //    // Sets the specified breakpoint

          //    Function ComSetBreakPoint String llfile UInteger ByRef llline Returns Boolean

                End_Procedure

              End_Object

            End_Object

            Procedure DisplayTabDetails

              Send LoadData of oBreakpointsGrid

            End_Procedure

          End_Object // TP

          Function Tab_Change Integer iToTab Integer ePointerMode Returns Integer

            Handle  hoToTab

            Integer iCurrentTab

            Integer iRetVal

            Get Current_Tab To iCurrentTab

            Forward Get Tab_Change iToTab ePointerMode To iRetVal

            If (iCurrentTab<>-1 and iRetval=0) Begin

              Get Tab_Page_Id iToTab To hoToTab

              If (hoToTab=oBreakPoints_TP) Begin

                Send DisplayTabDetails of hoToTab

              End

            End

            Function_Return iRetVal

          End_Function

        End_Object  // oDebug_TD

      End_Object // oDebugPanelSplitter

    End_Object // oSplitterContainer

#IF (FMAC_VERSION < 14)

  // Seems this was required in the past? Let's assume that was for earlier versions as VDF14, no time to test.

  Procedure OnResize

    Integer cxy cx cy

    Integer dxy dx dy

    Handle  hoEditor

    Get Client_Size To cxy

    Move (Hi(cxy))  To cy

    Move (Low(cxy)) To cx

    Get GUISize of oDebug_TD To dxy

    Move (Hi(dxy))  To dy

    Move (Low(dxy)) To dx

    Get phoEditor to hoEditor

    If (hoEditor) begin

      Set GUISize of hoEditor  To (cy - (dy + 82)) (cx-143)

      Send Adjust_Logicals

    End

  End_Procedure // OnResize

#ENDIF

  Procedure doSetCaptionLabel String sLabel

    Set Label To ("Debugging:"*sLabel)

  End_Procedure // doSetCaptionLabel

Cd_End_Object